2 files changed, 54 insertions, 0 deletions
diff --git a/kde-frameworks/kirigami/Manifest b/kde-frameworks/kirigami/Manifest
new file mode 100644
index 00000000000..50677072649
--- /dev/null
+++ b/kde-frameworks/kirigami/Manifest
@@ -0,0 +1 @@
+DIST kirigami2-5.109.0.tar.xz 382956 BLAKE2B 32c1626e665b198dd9242bf7a96a03bfac1a2ebad2e62a94d7c4275d8a3e2a990967084825e8f492b81a6d0cebd741b73200690bb47dae9eb7097d580fe53eb4 SHA512 5a03e0cc3e4740d8cfd11456a8d47e356cfbc8a38a48205f7e678c910b0bebba23f42879c64dbddb7f0e2fe37b245de381a5f1a8a37cf42736e4a1b42055b2af
diff --git a/kde-frameworks/kirigami/kirigami-5.109.0.ebuild b/kde-frameworks/kirigami/kirigami-5.109.0.ebuild
new file mode 100644
index 00000000000..41461e52090
--- /dev/null
+++ b/kde-frameworks/kirigami/kirigami-5.109.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_EXAMPLES="true"
+ECM_QTHELP="false"
+ECM_TEST="true"
+KDE_ORG_NAME="${PN}2"
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org toolchain-funcs
+
+DESCRIPTION="Lightweight user interface framework for mobile and convergent applications"
+HOMEPAGE="https://techbase.kde.org/Kirigami"
+EGIT_REPO_URI="${EGIT_REPO_URI/${PN}2/${PN}}"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+openmp"
+
+# requires package to already be installed
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=$(usex examples)
+		$(cmake_use_find_package openmp OpenMP)
+	)
+
+	ecm_src_configure
+}