blob: 96d8f57c2558cb566f1442fe059d1d93e0ae480a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
KFMIN=6.18.0
QTMIN=6.9.1
inherit ecm plasma.kde.org xdg
DESCRIPTION="KDE Plasma workspace"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS=""
IUSE="appstream +fontconfig +ksysguard networkmanager +policykit
screencast +semantic-desktop systemd telemetry +wallpaper-metadata +X"
REQUIRED_USE="fontconfig? ( X )"
RESTRICT="test"
# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
# slot op: various private QtWaylandClient headers
COMMON_DEPEND="
dev-libs/icu:=
>=dev-libs/wayland-1.15
>=dev-qt/qt5compat-${QTMIN}:6[qml]
>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,libinput,network,opengl,sql,sqlite,wayland,widgets,xml]
>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
>=dev-qt/qtlocation-${QTMIN}:6
>=dev-qt/qtpositioning-${QTMIN}:6
>=dev-qt/qtshadertools-${QTMIN}:6
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kbookmarks-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kdeclarative-${KFMIN}:6
>=kde-frameworks/kded-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kholidays-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kidletime-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/knotifyconfig-${KFMIN}:6
>=kde-frameworks/kpackage-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/krunner-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/ksvg-${KFMIN}:6
>=kde-frameworks/ktexteditor-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwallet-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/prison-${KFMIN}:6[qml]
>=kde-frameworks/solid-${KFMIN}:6
>=kde-plasma/breeze-${KDE_CATV}:6
>=kde-plasma/knighttime-${KDE_CATV}:6
>=kde-plasma/kwayland-${KDE_CATV}:6
>=kde-plasma/kwin-${KDE_CATV}:6
>=kde-plasma/layer-shell-qt-${KDE_CATV}:6
>=kde-plasma/libkscreen-${KDE_CATV}:6
>=kde-plasma/libplasma-${KDE_CATV}:6
>=kde-plasma/plasma-activities-${KDE_CATV}:6=
>=kde-plasma/plasma-activities-stats-${KDE_CATV}:6
>=kde-plasma/plasma5support-${KDE_CATV}:6
media-libs/libcanberra
sci-libs/libqalculate:=
sys-apps/dbus
virtual/zlib:=
virtual/libudev:=
appstream? ( >=dev-libs/appstream-1[qt6] )
ksysguard? ( >=kde-plasma/libksysguard-${KDE_CATV}:6 )
policykit? ( virtual/libcrypt:= )
networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:6 )
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:6 )
systemd? ( sys-apps/systemd:= )
telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
wallpaper-metadata? ( kde-apps/libkexiv2:6 )
X? (
>=dev-qt/qtbase-${QTMIN}:6=[X]
>=kde-plasma/kscreenlocker-${KDE_CATV}:6
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXau
x11-libs/libxcb
x11-libs/libXcursor
x11-libs/libXfixes
x11-libs/libXtst
x11-libs/xcb-util
fontconfig? (
media-libs/fontconfig
x11-libs/libXft
x11-libs/xcb-util-image
)
)
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/plasma-wayland-protocols-1.19.0
dev-libs/qcoro
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
test? ( screencast? ( >=media-video/pipewire-0.3:* ) )
X? (
fontconfig? ( x11-libs/libXrender )
x11-base/xorg-proto
)
"
RDEPEND="${COMMON_DEPEND}
!kde-plasma/libkworkspace:5
!<kde-plasma/plasma-desktop-6.3.80
!<kde-plasma/xdg-desktop-portal-kde-6.1.90
!kde-plasma/xembed-sni-proxy:*
app-text/iso-codes
dev-libs/kirigami-addons:6
>=dev-qt/qttools-${QTMIN}:*[qdbus]
kde-apps/kio-extras:6
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/kquickcharts-${KFMIN}:6
>=kde-plasma/kactivitymanagerd-${KDE_CATV}:6
>=kde-plasma/kdesu-gui-${KDE_CATV}:*
>=kde-plasma/milou-${KDE_CATV}:6
>=kde-plasma/plasma-integration-${KDE_CATV}:6
>=kde-plasma/plasma-login-sessions-${KDE_CATV}:6
sys-apps/dbus
x11-apps/xmessage
x11-apps/xprop
x11-apps/xrdb
policykit? ( sys-apps/accountsservice )
screencast? ( >=media-video/pipewire-0.3:* )
"
RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
BDEPEND="
>=dev-qt/qtbase-${QTMIN}:6[wayland]
>=dev-util/wayland-scanner-1.19.0
>=kde-frameworks/kcmutils-${KFMIN}:6
virtual/pkgconfig
test? ( >=dev-qt/qtwayland-${QTMIN}:6[compositor(+)] )
"
BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
PATCHES=(
"${FILESDIR}/${PN}-5.22.5-krunner-cwd-at-home.patch" # TODO upstream: KDE-bug 432975, bug 767478
)
src_prepare() {
ecm_src_prepare
cmake_comment_add_subdirectory login-sessions
sed -e "s/^find_package.*Phonon4Qt6/#&/" -i CMakeLists.txt || die
cmake_comment_add_subdirectory phonon # gone in >=6.6
if ! use policykit; then
cmake_comment_add_subdirectory -f kcms users
fi
if ! use fontconfig; then
ecm_punt_bogus_dep XCB IMAGE
sed -e "s/check_X11_lib(Xft)/#&/" -i CMakeLists.txt || die
fi
# TODO: try to get a build switch upstreamed
if ! use systemd; then
sed -e "s/^pkg_check_modules.*SYSTEMD/#&/" -i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
-DWITH_X11=$(usex X) # remember to submit patches with bugs
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON # not packaged
-DGLIBC_LOCALE_GEN=OFF
-DGLIBC_LOCALE_PREGENERATED=$(usex elibc_glibc)
$(cmake_use_find_package appstream AppStreamQt)
$(cmake_use_find_package fontconfig Fontconfig)
$(cmake_use_find_package ksysguard KSysGuard)
$(cmake_use_find_package networkmanager KF6NetworkManagerQt)
-DBUILD_CAMERAINDICATOR=$(usex screencast)
$(cmake_use_find_package semantic-desktop KF6Baloo)
$(cmake_use_find_package telemetry KF6UserFeedback)
$(cmake_use_find_package wallpaper-metadata KExiv2Qt6)
)
ecm_src_configure
}
src_install() {
ecm_src_install
# default startup and shutdown scripts
insinto /etc/xdg/plasma-workspace/env
doins "${FILESDIR}"/10-agent-startup.sh
insinto /etc/xdg/plasma-workspace/shutdown
doins "${FILESDIR}"/10-agent-shutdown.sh
fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
}
pkg_postinst () {
xdg_pkg_postinst
elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
}
|
