blob: 3fd7454b0016317d2110649185acb87d485188ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
KFMIN=9999
QTMIN=6.9.1
inherit ecm plasma.kde.org xdg
DESCRIPTION="Screenshot capture utility"
HOMEPAGE="https://apps.kde.org/spectacle/"
LICENSE="LGPL-2+ handbook? ( FDL-1.3 )"
SLOT="6"
KEYWORDS=""
IUSE="ocr share"
# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
COMMON_DEPEND="
dev-libs/wayland
>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,wayland,widgets,X]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtmultimedia-${QTMIN}:6[qml]
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/prison-${KFMIN}:6
>=kde-plasma/kpipewire-${KDE_CATV}:6
>=kde-plasma/layer-shell-qt-${KDE_CATV}:6
media-libs/kquickimageeditor:6
media-libs/opencv:=
x11-libs/libxcb
x11-libs/libXrandr
x11-libs/xcb-util
x11-libs/xcb-util-cursor
x11-libs/xcb-util-image
ocr? ( app-text/tesseract:= )
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/plasma-wayland-protocols-1.19.0
"
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtimageformats-${QTMIN}:6
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-frameworks/kimageformats-${KFMIN}:6
"
RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
BDEPEND="
>=dev-qt/qtbase-${QTMIN}:6[wayland]
dev-util/wayland-scanner
virtual/pkgconfig
"
BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
src_prepare() {
ecm_src_prepare
# TODO: try to get a build switch upstreamed
if ! use ocr; then
sed -e "s/^pkg_check_modules.*tesseract/#&/" \
-i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package share KF6Purpose)
)
ecm_src_configure
}
|
