kde-plasma: Add KDE Plasma 5.19 stable branch

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 68 insertions, 0 deletions

diff --git a/kde-plasma/systemsettings/systemsettings-5.19.49.9999.ebuild b/kde-plasma/systemsettings/systemsettings-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..168e5d423a2
--- /dev/null
+++ b/kde-plasma/systemsettings/systemsettings-5.19.49.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Control Center to configure KDE Plasma desktop"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-misc/systemd-kcm
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# FIXME: hangs in chroot; similar to bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*org\.kde\.kcm/#&/" \
+		-i CMakeLists.txt || die
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version kde-plasma/kde-gtk-config || \
+			elog "Install kde-plasma/kde-gtk-config to configure looks for GTK+."
+	fi
+}